; BandFilterII.csd
; Written by Iain McCurdy, 2015.
; Modify filter limits using the xypad
; The limit double slider is more just for display.
form caption("Bandfilter II"), colour("LightSlateGrey"), size(510, 655), pluginid("BFII"), scrollbars(0)
checkbox bounds(9,3,90,15), channel("TestSound"), text("Test Sound"), value(0), fontcolour("black")
xypad bounds(5,20, 500, 500), channel("shift", "width"), rangex(0, 1, 0.5), rangey(0, 1, 0.5), text("x:cutoff y:bandwidth"), colour("LightSlateGrey"), fontcolour("white")
;hslider2 bounds( 5,513,500, 40), channel("Lim1","Lim2"), min(4), max(14), range(4, 14, 0, 1, 0.001)
hrange bounds( 5,513, 500, 40), channel("Lim1","Lim2"), range(4, 14, 4:14, 1, 0.001)
;hslider bounds( 5,513,500,15), channel("Lim1"), range(4,14,4)
;hslider bounds( 5,528,500,15), channel("Lim2"), range(4,14,14)
label bounds( 5,543,500, 13), text("L I M I T S"), fontcolour("black")
image bounds( 5,560,155, 90), shape("sharp"), outlinecolour("black"), colour(0,0,0,0), outlinethickness(1)
checkbox bounds( 15,570, 80, 11), channel("HPF_active"), text("HPF Active"), fontcolour("black"), value(1)
label bounds( 15,595, 80, 13), text("HPF Type"), fontcolour("black")
combobox bounds( 15,610, 80, 20), value(2), channel("HPF_type"), text("6dB/oct","12dB/oct","24dB/oct","36dB/oct","48dB/oct","Resonant"), colour("black")
rslider bounds( 95,560, 60, 85), range(0,1,0), channel("HPF_res"), identchannel("HPF_resID"), text("Res"), textbox(1), colour("black"), fontcolour("black"), textcolour("black"), fontcolour("black")
image bounds(165,560,155, 90), shape("sharp"), outlinecolour("black"), colour(0,0,0,0), outlinethickness(1)
checkbox bounds(175,570, 80, 11), channel("LPF_active"), text("LPF Active"), fontcolour("black"), value(1)
label bounds(175,595, 80, 13), text("LPF Type"), fontcolour("black")
combobox bounds(175,610, 80, 20), value(2), channel("LPF_type"), text("6dB/oct","12dB/oct","24dB/oct","36dB/oct","48dB/oct","Resonant"), colour("black")
rslider bounds(255,560, 60, 85), range(0,1,0), channel("LPF_res"), identchannel("LPF_resID"), text("Res"), textbox(1), colour("black"), fontcolour("black"), textcolour("black")
label bounds(370,550, 95, 13), fontcolour("black"), text("Mode")
combobox bounds(370,565, 95, 20), channel("PassRej"), text("Bandpass","Bandreject","Bypass"), value(1)
label bounds(330,591,170,13), fontcolour("black"), text("Smoothing")
hslider bounds(330,605,170,15), range(0,0.1,0.03,0.75,0.0001), channel("Smoothing"), textcolour("black")
label bounds(330,621,170,13), fontcolour("black"), text("Gain")
hslider bounds(330,635,170,15), range(0,1,1), channel("Gain"), textcolour("black")
}
-dm0 -n -+rtmidi=NULL -M0
sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1
;Author: Iain McCurdy (2015)
opcode HighpassNetwork,aa,aakkk
aL,aR,kHPF,kHPF_res,kHPF_type xin
if kHPF_type==1 then
aL atone aL, cpsoct(kHPF)
aR atone aR, cpsoct(kHPF)
elseif kHPF_type==2 then
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
elseif kHPF_type==3 then
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
elseif kHPF_type==4 then
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
elseif kHPF_type==5 then
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
aL buthp aL, cpsoct(kHPF)
aR buthp aR, cpsoct(kHPF)
elseif kHPF_type==6 then
aL bqrez aL,cpsoct(kHPF),1+(kHPF_res*40),1
aR bqrez aR,cpsoct(kHPF),1+(kHPF_res*40),1
endif
xout aL,aR
endop
opcode LowpassNetwork,aa,aakkk
aL,aR,kLPF,kLPF_res,kLPF_type xin
if kLPF_type==1 then
aL tone aL, cpsoct(kLPF)
aR tone aR, cpsoct(kLPF)
elseif kLPF_type==2 then
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
elseif kLPF_type==3 then
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
elseif kLPF_type==4 then
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
elseif kLPF_type==5 then
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
aL butlp aL, cpsoct(kLPF)
aR butlp aR, cpsoct(kLPF)
elseif kLPF_type==6 then
aL moogladder aL,cpsoct(kLPF),kLPF_res
aR moogladder aR,cpsoct(kLPF),kLPF_res
endif
xout aL,aR
endop
instr 1
kshift chnget "shift"
kwidth chnget "width"
kgain chnget "Gain"
kPassRej chnget "PassRej"
kPassRej init 1
kTestSound chnget "TestSound"
kSmoothing chnget "Smoothing"
kLPF_type chnget "LPF_type"
kHPF_type chnget "HPF_type"
kLPF_type init 2
kHPF_type init 2
kLPF_res chnget "LPF_res"
kHPF_res chnget "HPF_res"
kLPF_active chnget "LPF_active"
kHPF_active chnget "HPF_active"
if changed(kHPF_type)==1 then
if kHPF_type==6 then
chnset "visible(1)","HPF_resID"
else
chnset "visible(0)","HPF_resID"
endif
endif
if changed(kLPF_type)==1 then
if kLPF_type==6 then
chnset "visible(1)","LPF_resID"
else
chnset "visible(0)","LPF_resID"
endif
endif
kLim1 limit scale:k(kshift-(kwidth*kshift),14,4), 4, 14
kLim2 limit scale:k(kshift+(kwidth*kshift),14,4), 4, 14
chnset kLim1,"Lim1"
chnset kLim2,"Lim2"
if kTestSound==1 then
aL pinkish 0.5 ; use for testing
aR pinkish 0.5 ; use for testing
else
aL,aR ins
endif
kporttime linseg 0,0.01,1
kporttime *= kSmoothing
kLim1 portk kLim1,kporttime
kLim2 portk kLim2,kporttime
if kPassRej==1 then
if kHPF_active==1 then
aL,aR HighpassNetwork aL,aR,kLim1,kHPF_res,kHPF_type
endif
if kLPF_active==1 then
aL,aR LowpassNetwork aL,aR,kLim2,kLPF_res,kLPF_type
endif
elseif kPassRej==2 then
if kHPF_active==1 then
aL1,aR1 HighpassNetwork aL,aR,kLim2,kHPF_res,kHPF_type
endif
if kLPF_active==1 then
aL2,aR2 LowpassNetwork aL,aR,kLim1,kLPF_res,kLPF_type
endif
aL1,aR1,aL2,aR2 init 0
aL sum aL1,aL2
aR sum aR1,aR2
clear aL1,aR1,aL2,aR2
endif
outs aL*kgain, aR*kgain
endin
i 1 0 [3600*24*7]